# Girder is a problem from structural design, the optimal design of a
# (steel) girder. See the detailed description in file girder.ps
# it has been supplied by a user of donlp2.
# written in AMPL by Yu-Ju Kuo and Hans D. Mittelmann, 6/2001
param   n := 4; 
var X{1..n};
param UG{1..n};
param OG{1..n};
param   nh := 0;
param   ng := 14;
param   L := 25;
param   E :=  210;
param   SY := 262;
param   SA := 0.55e0*SY;
param   TA := 0.33e0*SY;
param   ST := 255;
param   DA := L/800;
param   PM :=105;
param   PS :=155;
param   LLIMP:=1+50/(L+125);
var A=X[1]*X[4]+2.e0*X[2]*X[3];
var INER= X[4]*X[1]**3/12.e0+X[2]*X[3]**3*2.e0/3.e0
        +0.5e0*X[1]*X[2]*X[3]*(X[1]+2.e0*X[3]);
var W=19+77*A;
var M=L*(2*PM+W*L)/8;
var SS=M*(X[1]*.5+X[3])/(1000*INER);
var SF=72845.e0*(X[3]/X[2])**2;;
var SW=3648276.e0*(X[4]/X[1])**2;
var LS=(PS+W*L)*0.5e0;
var D=L**3*((8.e0*PM+5.e0*W*L)/(384.e0*E*INER*1.e6));
var T=LS/(1.e3*X[1]*X[4]);
minimize obj:L*(X[1]*X[4]+2*X[2]*X[3]);
s.t. g1: SA-SS>=0;     
s.t. g2: SF-SS>=0;
s.t. g3: SW-SS>=0;
s.t. g4: TA-T>=0;
s.t. g5: DA-D>=0;
s.t. g6: ST*.5-SS>=0;
s.t. g7i{i in 7..10}: X[i-6]-UG[i-6]>=0;
s.t. g11i{i in 11..ng}:OG[i-10]-X[i-10]>=0;

data;
var X:=   1  1.4 2 1.4 3 0.055 4 0.0105;
param UG:= 1 0.3 2 0.3 3 0.01  4 0.01;
param OG:= 1 2.5 2 2.5 3 0.1 4 0.0115;